View source for VR

== Monado ==

[https://monado.freedesktop.org/ Monado] is an open source OpenXR runtime. It offers support for a variety of hardware using its built-in drivers and can be used to run any OpenXR and, with the help of OpenComposite, most OpenVR applications.

Monado can be configured using its NixOS options since 24.05:

{{file|/etc/nixos/configuration.nix|nix|3=services.monado = {
  enable = true;
  defaultRuntime = true; # Register as default OpenXR runtime
};}}

In order to configure Monado, you might want to add additional environment variables:

{{file|/etc/nixos/configuration.nix|nix|3=systemd.user.services.monado.environment = {
  STEAMVR_LH_ENABLE = "1";
  XRT_COMPOSITOR_COMPUTE = "1";
};}}

=== Hand Tracking ===

You may notice that running <code>monado-services</code> will fail due to the lack of hand tracking data.  There are 2 ways to remedy this, either disable hand tracking altogether, or download the hand tracking data.

To disable hand tracking, modify the environment variable to include <code>WMR_HANDTRACKING = "0";</code>, so that it will look like this.

{{file|/etc/nixos/configuration.nix|nix|3=systemd.user.services.monado.environment = {
  STEAMVR_LH_ENABLE = "1";
  XRT_COMPOSITOR_COMPUTE = "1";
  WMR_HANDTRACKING = "0";
};}}

To get hand tracking to work, you require <code>git-lfs</code> to be enabled.  The standard way of enabling <code>git-lfs</code> is through the configuration below
{{file|/etc/nixos/configuration.nix|nix|3=programs.git = {
  enable = true;
  lfs.enable = true;
};}}

After making sure <code>git-lfs</code> is enabled, run these commands and restart <code>monado-service</code>
{{Commands|
$ mkdir -p ~/.local/share/monado
$ cd ~/.local/share/monado
$ git clone https://gitlab.freedesktop.org/monado/utilities/hand-tracking-models
}}


For further information about available environment variables and tweaks, read the [https://lvra.gitlab.io/docs/fossvr/monado/ Linux VR Adventures wiki] and the [https://monado.freedesktop.org/getting-started.html#environment-variables Monado documentation about environment variables]

== OpenComposite ==

[https://gitlab.com/znixian/OpenOVR OpenComposite] is a compatibility layer for running OpenVR applications on an OpenXR runtime like Monado. It is comparable to tools like DXVK or vkd3d, but for translating OpenVR calls to OpenXR.

In order to run OpenVR games on anything other than SteamVR, you need to configure the OpenVR runtime path defined in <code>~/.config/openvr/openvrpaths.vrpath</code>. A reliable way to do this is to use [[Home Manager]] to create this file.

If this file is not set to read-only, SteamVR will add its runtime path back, hence the use for Home Manager.

{{Warning|Proton will always query the current OpenVR and OpenXR runtime. If you use OpenComposite, and it fails to initialize an OpenXR context, Proton will fail to launch. A workaround is to delete the ~/.config/openvr/openvrpaths.vrpath file and then retry launching the game.}}

An example configuration for enabling OpenComposite may look like this:

{{file|~/.config/home-manager/home.nix|nix|3=xdg.configFile."openxr/1/active_runtime.json".text = ''
  {
    "file_format_version": "1.0.0",
    "runtime": {
        "name": "Monado",
        "library_path": "${pkgs.monado}/lib/libopenxr_monado.so"
    }
  }
'';

xdg.configFile."openvr/openvrpaths.vrpath".text = ''
  {
    "config" :
    [
      "${config.xdg.dataHome}/Steam/config"
    ],
    "external_drivers" : null,
    "jsonid" : "vrpathreg",
    "log" :
    [
      "${config.xdg.dataHome}/Steam/logs"
    ],
    "runtime" :
    [
      "${pkgs.opencomposite}/lib/opencomposite"
    ],
    "version" : 1
  }
'';}}

If you are planning to play any OpenVR game on Steam or OpenXR games through Proton, you will have to use OpenComposite in this manner. In most cases you also have to allow access to the socket path of your OpenXR runtime to Steam's runtime, by using the following launch options for XR applications on Steam: <code>env PRESSURE_VESSEL_FILESYSTEMS_RW=$XDG_RUNTIME_DIR/monado_comp_ipc %command%</code>. This example is for Monado, while other XR runtimes might differ.

== WiVRn ==
With the merging of https://github.com/NixOS/nixpkgs/pull/316975, [https://github.com/WiVRn/WiVRn WiVRn] is now in Nixpkgs with a module.

Example usage of the WiVRn module:<syntaxhighlight lang="nix">
  services.wivrn = {
    enable = true;
    openFirewall = true;

    # Write information to /etc/xdg/openxr/1/active_runtime.json, VR applications
    # will automatically read this and work with wivrn
    defaultRuntime = true;

    # Executing it through the systemd service executes WiVRn w/ CAP_SYS_NICE
    # Resulting in no stutters!
    autoStart = true;

    # Config for WiVRn (https://github.com/WiVRn/WiVRn/blob/master/docs/configuration.md)
    config = {
      enable = true;
      json = {
        # 1.0x display scaling
        scale = 1.0;
        # 100 Mb/s
        bitrate = 100000000;
        encoders = [
          {
            encoder = "vaapi";
            codec = "h265";
            # 1.0 x 1.0 scaling
            width = 1.0;
            height = 1.0;
            offset_x = 0.0;
            offset_y = 0.0;
          }
        ];
      };
    };
  };

</syntaxhighlight>

=== WiVRn + Steam ===
For each VR game, go to Properties > Launch Options and put:<syntaxhighlight lang="shell">
PRESSURE_VESSEL_FILESYSTEMS_RW=$XDG_RUNTIME_DIR/wivrn/comp_ipc %command%
</syntaxhighlight>This will tell proton/steam to use wivrn when that game is ran.

== SteamVR ==
[https://store.steampowered.com/app/250820/SteamVR/ SteamVR] is a proprietary OpenVR runtime with compatibility for OpenXR. It is part of [[Steam]] and doesn't need any additional setup on NixOS apart from enabling Steam.

After installing SteamVR through Steam and plugging in a SteamVR-compatible headset, SteamVR should work for the most part.

On initial setup, SteamVR will ask for elevated permissions, to set up a file capability for one of its binaries. This is needed to allow asynchronous reprojection to work. Clients need the <code>CAP_SYS_NICE</code> capability to acquire a high-priority context, which is a requirement for asynchronous reprojection.

{{Note|Steam is run in a bubblewrap-based FHS environment. This environment runs Steam in a user namespace, which prevents it from using any capabilities or setuid binaries. This means that asynchronous reprojection can not be used on NixOS, without patching the kernel to remove these restrictions completely. See this [https://github.com/NixOS/nixpkgs/issues/217119 Nixpkgs issue]}}

=== Patching AMDGPU to allow high priority queues ===

By applying [https://github.com/Frogging-Family/community-patches/blob/a6a468420c0df18d51342ac6864ecd3f99f7011e/linux61-tkg/cap_sys_nice_begone.mypatch this patch], the AMDGPU kernel driver will ignore process privileges and allow any application to create high priority contexts.

{{Warning|This removes intentional restrictions from the kernel, and it could cause scheduling issues. While it has not been reported that it does cause issues, this should be considered an unsupported configuration.}}

==== Applying as a NixOS kernel patch ====

To workaround the <code>CAP_SYS_NICE</code> requirement, we can apply a kernel patch using the following NixOS configuration snippet:

{{file|/etc/nixos/configuration.nix|nix|3=boot.kernelPatches = [
  {
    name = "amdgpu-ignore-ctx-privileges";
    patch = pkgs.fetchpatch {
      name = "cap_sys_nice_begone.patch";
      url = "https://github.com/Frogging-Family/community-patches/raw/master/linux61-tkg/cap_sys_nice_begone.mypatch";
      hash = "sha256-Y3a0+x2xvHsfLax/uwycdJf3xLxvVfkfDVqjkxNaYEo=";
    };
  }
];
}}

It is also possible to just patch amdgpu and build it as an out-of-tree module, as described in [[Linux_kernel#Patching_a_single_In-tree_kernel_module]]

=== wlx-overlay-s ===
[https://github.com/galister/wlx-overlay-s wlx-overlay-s] is a lightweight OpenXR/OpenVR overlay for Wayland and X11 desktops. It works with SteamVR as well as Monado/WiVRn natively.

==== SteamVR autostart ====
When launching wlx-overlay-s in SteamVR (or any OpenVR compositor) it will register an autostart manifest. Currently, this manifest will reference a Nix store path of wlx-overlay-s, which might get garbage collected after rebuilds of your NixOS/Nix profile. A workaround is to regularly run the following command to update the manifest's store path:{{Commands|
# Run wlx-overlay-s and replace any running instance
$ wlx-overlay-s --replace}}
== See also ==

* [https://lvra.gitlab.io Linux VR Adventures Wiki]
[[Category:Video]]
[[Category:Hardware]]