Создание Live CD образа NixOS

Мотивация

Создание модифицированного NixOS LiveCD на основе существующей рабочей установки NixOS имеет ряд преимуществ:

Гарантирует подлинность.
Нет необходимости в доступе в Интернет.
В образ легко добавлять собственные пакеты и изменения конфигурации.

Building

Building minimal NixOS installation CD with the nix-build command by creating this iso.nix-file. In this example with Neovim preinstalled.

{ config, pkgs, ... }:
{
  imports = [
    <nixpkgs/nixos/modules/installer/cd-dvd/installation-cd-minimal.nix>

    # Provide an initial copy of the NixOS channel so that the user
    # doesn't need to run "nix-channel --update" first.
    <nixpkgs/nixos/modules/installer/cd-dvd/channel.nix>
  ];
  environment.systemPackages = [ pkgs.neovim ];
}

Соберите образ через:

nix-build '<nixpkgs/nixos>' -A config.system.build.isoImage -I nixos-config=iso.nix

В качестве альтернативы используйте Nix Flakes для создания установочного образа ISO, используя ветку nixos-24.05 в качестве источника nixpkgs:

flake.nix

{
  description = "Minimal NixOS installation media";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
  outputs = { self, nixpkgs }: {
    nixosConfigurations = {
      exampleIso = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          ({ pkgs, modulesPath, ... }: {
            imports = [ (modulesPath + "/installer/cd-dvd/installation-cd-minimal.nix") ];
            environment.systemPackages = [ pkgs.neovim ];
          })
        ];
      };
    };
  };
}

Следующие комманды сгенерируют iso-образ:

# git init
# git add flake.nix
# nix build .#nixosConfigurations.exampleIso.config.system.build.isoImage

Готовый ISO-образ может быть найден в result/

$ ls result/iso/
nixos-24.05.20240721.63d37cc-x86_64-linux.iso

Тестирование образа

Чтобы просмотреть содержимое ISO-образа:

$ mkdir mnt
$ sudo mount -o loop result/iso/nixos-*.iso mnt
$ ls mnt
boot  EFI  isolinux  nix-store.squashfs  version.txt
$ umount mnt

Чтобы загрузиться в ISO-оьраз в эмуляторе:

$ nix-shell -p qemu
$ qemu-system-x86_64 -enable-kvm -m 256 -cdrom result/iso/nixos-*.iso

SSH

В вашем iso.nix

{
  ...
  # Enable SSH in the boot process.
  systemd.services.sshd.wantedBy = pkgs.lib.mkForce [ "multi-user.target" ];
  users.users.root.openssh.authorizedKeys.keys = [
    "ssh-ed25519 AaAeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee username@host"
  ];
  ...
}

Статический IP-адрес

Статические IP-адреса можно задать в образе. Это может быть полезно для установки на VPS.

{
  ...
  networking = {
    usePredictableInterfaceNames = false;
    interfaces.eth0.ip4 = [{
      address = "64.137.201.46";
      prefixLength = 24;
    }];
    defaultGateway = "64.137.201.1";
    nameservers = [ "8.8.8.8" ];
  };
  ...
}

Ускорение сборки

Процесс сборки является медленным из-за сжатия.

Вот некоторые сроки для nix-build:

Compression results
squashfsCompression	Time	Size
`lz4`	100s	59%
`gzip -Xcompression-level 1`	105s	52%
`gzip`	210s	49%
`xz -Xdict-size 100%` (default)	450s	43%

См. Также

Мануал NixOS: Сборка NixOS (Live) ISO.