View source for Creating a NixOS live CD/en

== Motivation ==
Creating a modified NixOS LiveCD out of an existing working NixOS installation has a number of benefits:
* Ensures authenticity.
* No need for internet access.
* It is easy to add your own packages and configuration changes to the image.
== Building ==
Building minimal NixOS installation CD with the <code>nix-build</code> command by creating this <code>iso.nix</code>-file. In this example with [[Neovim]] preinstalled. 
<syntaxhighlight lang="nix">
{ config, pkgs, ... }:
{
  imports = [
    <nixpkgs/nixos/modules/installer/cd-dvd/installation-cd-minimal.nix>

    # Provide an initial copy of the NixOS channel so that the user
    # doesn't need to run "nix-channel --update" first.
    <nixpkgs/nixos/modules/installer/cd-dvd/channel.nix>
  ];
  environment.systemPackages = [ pkgs.neovim ];
}
</syntaxhighlight>
Build the image via:
<syntaxhighlight lang="bash">
nix-build '<nixpkgs/nixos>' -A config.system.build.isoImage -I nixos-config=iso.nix
</syntaxhighlight>
Alternatively, use Nix [[Flakes]] to generate a ISO installation image, using the <code>nixos-24.05</code> branch as nixpkgs source:
{{file|flake.nix|nix|<nowiki>
{
  description = "Minimal NixOS installation media";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.05";
  outputs = { self, nixpkgs }: {
    nixosConfigurations = {
      exampleIso = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          ({ pkgs, modulesPath, ... }: {
            imports = [ (modulesPath + "/installer/cd-dvd/installation-cd-minimal.nix") ];
            environment.systemPackages = [ pkgs.neovim ];
          })
        ];
      };
    };
  };
}
</nowiki>}}
The following commands will generate the iso-image:
<syntaxhighlight lang="console">
# git init
# git add flake.nix
# nix build .#nixosConfigurations.exampleIso.config.system.build.isoImage
</syntaxhighlight>
The resulting image can be found in <code>result</code>:
<syntaxhighlight lang="console">
$ ls result/iso/
nixos-24.05.20240721.63d37cc-x86_64-linux.iso
</syntaxhighlight>
=== Testing the image ===

To inspect the contents of the ISO image:
<syntaxhighlight lang="console">
$ mkdir mnt
$ sudo mount -o loop result/iso/nixos-*.iso mnt
$ ls mnt
boot  EFI  isolinux  nix-store.squashfs  version.txt
$ umount mnt
</syntaxhighlight>
To boot the ISO image in an emulator:
<syntaxhighlight lang="console">
$ nix-shell -p qemu
$ qemu-system-x86_64 -enable-kvm -m 256 -cdrom result/iso/nixos-*.iso
</syntaxhighlight>
===SSH===
In your <tt>iso.nix</tt>:
<syntaxhighlight lang="nix">
{
  ...
  # Enable SSH in the boot process.
  systemd.services.sshd.wantedBy = pkgs.lib.mkForce [ "multi-user.target" ];
  users.users.root.openssh.authorizedKeys.keys = [
    "ssh-ed25519 AaAeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee username@host"
  ];
  ...
}
</syntaxhighlight>
===Static IP Address===

Static IP addresses can be set in the image itself. This can be useful for VPS installation.
<syntaxhighlight lang="nix">
{
  ...
  networking = {
    usePredictableInterfaceNames = false;
    interfaces.eth0.ip4 = [{
      address = "64.137.201.46";
      prefixLength = 24;
    }];
    defaultGateway = "64.137.201.1";
    nameservers = [ "8.8.8.8" ];
  };
  ...
}
</syntaxhighlight>
=== Building faster ===
The build process is slow because of compression.

Here are some timings for <code>nix-build</code>:
{| class="wikitable" style="margin:auto"
|+ Compression results
|-
! squashfsCompression !! Time !! Size
|-
| <code>lz4</code> || 100s || 59%
|-
| <code>gzip -Xcompression-level 1</code> || 105s || 52%
|-
| <code>gzip</code> || 210s || 49%
|-
| <code>xz -Xdict-size 100%</code> (default) || 450s || 43%
|}
See also: [https://gist.github.com/baryluk/70a99b5f26df4671378dd05afef97fce mksquashfs benchmarks]

If you don't care about file size, you can use a faster compression
by adding this to your <code>iso.nix</code>:
<syntaxhighlight lang="nix">
{
  isoImage.squashfsCompression = "gzip -Xcompression-level 1";
}
</syntaxhighlight>
==See also==
* [https://nixos.org/manual/nixos/stable/index.html#sec-building-image NixOS Manual: Building a NixOS (Live) ISO].
[[Category:NixOS]]
[[Category:Deployment]]
[[Category:Cookbook]]