View source for Shell scripts/zh

<languages/>

<div lang="en" dir="ltr" class="mw-content-ltr">
The package <code>writeShellScript</code> can be used to add shell scripts to Nix expressions.
</div>

<syntaxHighlight lang="nix">
someBuildHelper = { name, sha256 }:
  stdenv.mkDerivation {
    inherit name;
    outputHashMode = "recursive";
    outputHashAlgo = "sha256";
    outputHash = sha256;
    builder = writeShellScript "builder.sh" ''
      echo "hi, my name is ''${0}" # escape bash variable
      echo "hi, my hash is ${sha256}" # use nix variable
      echo "hello world" >output.txt
    '';
  };
</syntaxHighlight>

<div lang="en" dir="ltr" class="mw-content-ltr">
== External builder.sh script ==
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
Longer Bash scripts are usually stored as external script files, and called from Nix:
</div>

{{file|default.nix|nix|3=
{
  outputTxtDrv = stdenv.mkDerivation rec {
    name = "output.txt";
    # disable unpackPhase etc
    phases = "buildPhase";
    builder = ./builder.sh;
    nativeBuildInputs = [ coreutils jq ];
    PATH = lib.makeBinPath nativeBuildInputs;
    # only strings can be passed to builder
    someString = "hello";
    someNumber = builtins.toString 42;
    someJson = builtins.toJSON { dst = "world"; };
  };
}
}}

{{file|builder.sh|sh|3=
echo "$someString $(echo "$someJson" | jq -r '.dst') $someNumber" >$out
}}

<div lang="en" dir="ltr" class="mw-content-ltr">
See also:
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
* [https://github.com/NixOS/nixpkgs/issues/23099 Make a derivation with no source]
* [https://nixos.org/guides/nix-pills/working-derivation.html Nix Pills: Chapter 7. Working Derivation]
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
=== runCommand + builder.sh ===
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
Instead of <code>stdenv.mkDerivation</code>, <code>runCommand</code> can also be used to call an external Bash script:
</div>

{{file|default.nix|nix|3=
{
  outputTxtDrv = runCommand "output.txt" {
    nativeBuildInputs = [ coreutils jq ];
    # only strings can be passed to builder
    someString = "hello";
    someNumber = builtins.toString 42;
    someJson = builtins.toJSON { dst = "world"; };
  } (builtins.readFile ./builder.sh);
}
}}

<div lang="en" dir="ltr" class="mw-content-ltr">
== Packaging ==
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
Example:
</div>

<syntaxHighlight lang="nix">
# nix-build -E 'with import <nixpkgs> { }; callPackage ./default.nix { }'

{ stdenv
, lib
, fetchFromGitHub
, bash
, subversion
, makeWrapper
}:
  stdenv.mkDerivation {
    pname = "github-downloader";
    version = "08049f6";
    src = fetchFromGitHub {
      # https://github.com/Decad/github-downloader
      owner = "Decad";
      repo = "github-downloader";
      rev = "08049f6183e559a9a97b1d144c070a36118cca97";
      sha256 = "073jkky5svrb7hmbx3ycgzpb37hdap7nd9i0id5b5yxlcnf7930r";
    };
    buildInputs = [ bash subversion ];
    nativeBuildInputs = [ makeWrapper ];
    installPhase = ''
      mkdir -p $out/bin
      cp github-downloader.sh $out/bin/github-downloader.sh
      wrapProgram $out/bin/github-downloader.sh \
        --prefix PATH : ${lib.makeBinPath [ bash subversion ]}
    '';
  }
</syntaxHighlight>

<div lang="en" dir="ltr" class="mw-content-ltr">
<code>wrapProgram</code> will move the original script to <code>.github-downloader.sh-wrapped</code>.
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
=== Command not found ===
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
For example, the script throws the error <code>svn: command not found</code>, because the dependency <code>subversion</code> is missing.
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
When a command is missing, you can use <code>nix-locate</code> to find the package name. for example, the <code>stat</code> command:
</div>

<syntaxHighlight lang="console">
$ nix-locate bin/stat | grep 'bin/stat$'
coreutils.out       0 s /nix/store/vr96j3cxj75xsczl8pzrgsv1k57hcxyp-coreutils-8.31/bin/stat
</syntaxHighlight>

<div lang="en" dir="ltr" class="mw-content-ltr">
== Debugging embedded scripts ==
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
When a bash script fails, it prints only an error message, but no code location.
</div>

<div lang="en" dir="ltr" class="mw-content-ltr">
To trace commands and line numbers, one can use
</div>

{{file|test-trace.nix|nix|3=
{ runCommand, coreutils }:
runCommand "output.txt" { nativeBuildInputs = [ coreutils ]; } ''
  # line 5 in nix file = line 1 in bash script -> offset 4
  PS4='+ Line $(expr $LINENO + 4): '
  set -o xtrace # print commands

  echo hello >$out # line 9 in nix file

  set +o xtrace # hide commands
''

}}

<syntaxHighlight lang="console">
$ nix-build -E 'with import <nixpkgs> { }; callPackage ./test-trace.nix { }'
this derivation will be built:
  /nix/store/2v5biwny8plpyk2bv6cfr41ppp0a1i4k-output.txt.drv
building '/nix/store/2v5biwny8plpyk2bv6cfr41ppp0a1i4k-output.txt.drv'...
++ Line 9: echo hello
++ Line 11: set +o xtrace
/nix/store/ppidmnpd5m762x9kqj8jd3g7df7dknrz-output.txt
</syntaxHighlight>

<div lang="en" dir="ltr" class="mw-content-ltr">
== POSIX shell ==
</div>

某些环境（例如基于 BusyBox 的 OpenWRT）仅提供“受限” Shell（使用 <code>sh</code> 而非 <code>bash</code>）

在 NixOS 上，POSIX shells 由软件包 <code>dash</code> 和 <code>posh</code> 提供。

<span id="See_also"></span>
== 另见 ==

* [[Nix-shell shebang|Nix-shell shebang]]
* [https://nixos.org/manual/nixpkgs/stable/#ssec-stdenv-functions Nixpkgs 手册中的 Shell 函数章节]
* [https://gist.github.com/travisbhartwell/f972aab227306edfcfea nix-shell 和 Shebang 行]
* [https://ertt.ca/nix/shell-scripts/ 使用 Nix 的 Shell 脚本]

[[Category:Development{{#translation:}}|Shell scripts]]
[[Category:Shell{{#translation:}}|Shell scripts]]