View source for Helm and Helmfile

== HELM and HELMFILE ==

Using '''Helm''' and '''Helmfile''' on '''NixOS''' effectivly requires some minor setup.

== HELM ==

The derivation for <code>helm</code> is in <code>nixpkgs</code> und the name <code>kubernetes-helm</code>. However it does not include any plugins for helm.

To see which plugins are avaiable in <code>nixpkgs</code> do a <code>nix search nixpkgs kubernetes-helmPlugins</code>.

In order to make any plugins available to <code>helm</code> itself, <code>nixpkgs</code> provides a helper function called <code>wrapHelm</code>. This allows you to set an attribute called <code>plugins</code>.

The following snippet will give you access to helm with four plugins via your list of system packages. It assumes that you are using <code>nixpkgs</code> as <code>pkgs</code>:

<syntaxhighlight lang="nix">
{
  environment.systemPackages = with pkgs; [
      (wrapHelm kubernetes-helm {
        plugins = with pkgs.kubernetes-helmPlugins; [
          helm-secrets
          helm-diff
          helm-s3
          helm-git
        ];
      }) 
    ];
}
</syntaxhighlight>

Alternatively a self-contained flake for a development shell with helm and plugins available might look like this:

<syntaxhighlight lang="nix">
{
  description = "Nix flake for Helm";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/master";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let pkgs = nixpkgs.legacyPackages.${system}; in
      {
        devShells.default = pkgs.mkShell {
          name = "helm devShell";
          nativeBuildInputs = [ pkgs.bashInteractive ];
          buildInputs = with pkgs; [
            (wrapHelm kubernetes-helm {
              plugins = with pkgs.kubernetes-helmPlugins; [
                helm-diff
                helm-secrets
                helm-s3
              ];
            })
          ];
        };
      });
}
</syntaxhighlight>

Create a <code>flake.nix</code> in some empty directory, paste the snippet above and run it with <code>nix develop</code>

This will create a devShell with helm and listed plugins available. Check <code>helm plugin list</code> to verify. 


=== HELMFILE ===

Helmfile can be found in <code>nixpkgs</code> as <code>helmfile</code>.

In order to work properly, <code>helmfile</code> requires access to a number of helm plugins aside from the helm binary itself. In version 0.146.0, helmfile has introduced a check for plugin versions which uses helm's Go API directly instead of calling the helm binary. In order to make plugins avaiable after this change, the nix derivation <code>kubernetes-helm-wrapped</code> exposes an attribute called <code>pluginsDir</code> if helm is wrapped with plugins. The <code>helmfile</code> binary needs to be wrapped in turn in order to have access to this attribute.

There are several ways to achieve this. One is using an overlay inside a flake to populate the <code>pluginsDir</code> attribute.

<syntaxhighlight lang="nix">
{
  description = "Nix flake for Helm and Helmfile with plugins";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/master";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          system = "x86_64-linux";
          overlays = [
            (final: prev: rec {
              kubernetes-helm-wrapped = prev.wrapHelm prev.kubernetes-helm {
                plugins = with prev.kubernetes-helmPlugins; [
                  helm-diff
                  helm-secrets
                  helm-s3
                ];
              };
            })
          ];
        };
      in
      {
        devShells.default = pkgs.mkShell {
          name = "helmfile devShell";
          nativeBuildInputs = with pkgs; [
            bashInteractive
          ];
          buildInputs = with pkgs; [
            kubernetes-helm-wrapped
            helmfile-wrapped
          ];
        };
      });
}
</syntaxhighlight>

Here <code>helmfile-wrapped</code> reads <code>kubernetes-helm-wrapped.passthru.pluginsDir</code> and picks up the plugins correctly.

Again, create a <code>flake.nix</code> in some empty directory, paste the snippet above and run it with <code>nix develop</code>

This time it will create a devShell with helm and helmfile and listed plugins available. Check <code>helm plugin list</code> to verify for helm. Likewise check <code>helmfile init</code> to see if helmfile finds its helm plugin dependencies.

-----------------

Another approach is via a <code>let ... in</code> block in your <code>configuration.nix</code>.

<syntaxhighlight lang="nix">
{ config, pkgs, ... }:
let
  my-kubernetes-helm = with pkgs; wrapHelm kubernetes-helm {
    plugins = with pkgs.kubernetes-helmPlugins; [
      helm-secrets
      helm-diff
      helm-s3
      helm-git
    ];
  };

  my-helmfile = pkgs.helmfile-wrapped.override {
    inherit (my-kubernetes-helm) pluginsDir;
  };
in

{
  environment.systemPackages =  [
    my-kubernetes-helm
    my-helmfile
  ];
}
</syntaxhighlight>

Create a new <code>*.nix</code> file for the code snippet and import it into your system <code>configuration.nix</code>. In this case it  should make <code>helm</code> and <code>helmfile</code> with plugins available to your system.

== References ==

[https://github.com/NixOS/nixpkgs/issues/217768 Issue #217768]: helmfile does not recognize helm plugins
[https://discourse.nixos.org/t/helm-plugin-install/20705/3 NixOS Discourse]: Helm plugin install

[[Category:Applications]]
[[Category:Server]]
[[Category:Container]]