KDE

KDE Plasma is a desktop environment that aims to be simple by default, powerful when needed.

Installation

Plasma 6

❄︎ /etc/nixos/configuration.nix

# Enable Plasma 
services.desktopManager.plasma6.enable = true;

# Default display manager for Plasma
services.displayManager.sddm = {
  enable = true;
  
# To use Wayland (Experimental for SDDM)
  wayland = {
    enable = true;
    compositor = "kwin";
  };
};

# Optionally enable xserver
services.xserver.enable = true;

Plasma 5

❄︎ /etc/nixos/configuration.nix

# Enable Plasma 5 and xserver
services.xserver = {
  enable = true;
  desktopManager.plasma5.enable = true;
};

# Enable the default display manager
services.displayManager.sddm.enable = true;

Note: As of 2024, KDE Plasma 5 is end of life will not be available after NixOS 25.05.

Configuration

Rootless X11

sddm launches X11 as a root user by default. For better security, X11 can be run as a non-root user, but using Wayland is better tested and thus preferred:

# Using X11 as a non-root user
services.displayManager.sddm.settings.General.DisplayServer = "x11-user";

# Using Wayland (preferred)
services.displayManager.sddm.settings.General.DisplayServer = "wayland";

Excluding applications from the default install

Some optional packages can be excluded if they are not needed at the cost of functionality.

Plasma 6

Optional packages: plasma6.nix

environment.plasma6.excludePackages = with pkgs.kdePackages; [
  plasma-browser-integration
  konsole
  elisa
];

Plasma 5

Optional packages: plasma5.nix

environment.plasma5.excludePackages = with pkgs.libsForQt5; [
  plasma-browser-integration
  konsole
  oxygen
];

Default Wayland/X11 session

Plasma 6

Plasma 6 runs on Wayland by default. To launch an X11 session by default:

services.displayManager.defaultSession = "plasmax11";

SDDM on Wayland

services.displayManager.sddm.wayland.enable = true;

Plasma 5

Plasma 5 runs on X11 by default and it is recommended to use Wayland with Plasma 6 instead. To launch a Wayland session by default anyway:

services.displayManager.defaultSession = "plasmawayland";

Troubleshooting

Qt/KDE applications segfault on start

This is caused by a stale QML cache (see this issue). A dirty way to fix this is by running on a terminal the following command:

find ${XDG_CACHE_HOME:-$HOME/.cache}/**/qmlcache -type f -delete

GTK themes are not applied in Wayland applications / Window Decorations missing / Cursor looks different

This affects GTK applications including Firefox and Thunderbird.

You may need to set a GTK theme Breeze imitating the KDE theme with the same name in System Settings -> Application Style -->Configure GNOME/GTK Application Style.

(See this issue)

After Update to Plasma 6 Signal-Desktop complains about a Database Error involving kwallet5

1. Close Signal
2. Open ~/.config/Signal/config.json
3. Replace "safeStorageBackend": "kwallet5" with "safeStorageBackend": "kwallet6" (change 5 to 6)
4. Start Signal

Bluetooth configuration not available

Add the following configuration (generally in hardware-configuration.nix):

 hardware.bluetooth.enable = true;

This will add the following packages:

[
 bluedevil
 bluez-qt
 pkgs.openobex
 pkgs.obexftp
]

Brightness and Color brightness control sets gamma instead of brightness on external monitors

To allow powerdevil (and by extension the "Brightness and Color" status tray menu) to control brightness on supported monitors directly instead of adjusting gamma, configure your system to enable ddcutil, and allow your user to use DDC/CI without root.

Tips and tricks

Plasma-Manager

Note: Plasma-Manager is an unofficial community project and is not yet mature

By default, the Plasma configuration can be handled like on traditional systems. With plasma-manager, it is possible to make Plasma configurations via nix by providing home-manager modules.

User icon (avatar)

You can add a profile picture to your user by using a png file in ~/.face.icon.

Hacking

There are many reasons to modify the KDE packages, such as testing patches from other KDE developers, applying a fix before it is officially released and finds its way into nixpkgs or developing contributions for the KDE project.

Customizing nixpkgs

To override KDE packages, the common way using overrideAttrs won't work, since they are part of the kdePackagesscope, which requires the usage of overrideScope first:

nixpkgs-overlay = final: prev: {
  kdePackages = prev.kdePackages.overrideScope(kdeFinal: kdePrev: {
    somepackage = kdePrev.somepackage.overrideAttrs(prevPkgAttrs: {
      someattribute = …;
    };
  };
};

The following examples will demonstrate various ways how to achieve the customization of the KDE package powerdevil in different scenarios:

Using a single diff from a remote URL

A KDE developer might have provided a diff that one wants to utilize locally to test it or to make use of it until it's included in an upcoming release.

1. Generate the SRI hash of the file: nix store prefetch-file https://invent.kde.org/plasma/powerdevil/-/commit/f731c18e377b87c57f7205d9c1812a34f588c577.diff --json --name toggle-nightlight.diff
2. Override the patches attribute of the powerdevilpackage:

   kdePackages = prev.kdePackages.overrideScope(kdeFinal: kdePrev: {
     powerdevil = kdePrev.powerdevil.overrideAttrs (prevPdAttrs: {
       patches = prevPdAttrs.patches or [] ++ [
         (prev.fetchpatch {
           name = "toggle-nightlight.diff";
           url = "https://invent.kde.org/plasma/powerdevil/-/commit/f731c18e377b87c57f7205d9c1812a34f588c577.diff";
           sha256 = "sha256-X0ZHSRnSLqmp2fcLGx9DUTn7F9BFh5puh9Q4YAj6/5o=";
         })
       ];
     });
   });
   

Using commits of a repository

Either a local clone or remote repository might provide the code that should be used to build the package in question instead.

Remote repository

kdePackages = prev.kdePackages.overrideScope(kdeFinal: kdePrev: {
  powerdevil = kdePrev.powerdevil.overrideAttrs (prevPdAttrs: {
    src = builtins.fetchGit {
      url = "https://invent.kde.org/plasma/powerdevil";
      rev = "f731c18e377b87c57f7205d9c1812a34f588c577";
    };
  });
});

Local repository

Note: This will ignore files that are present in the worktree, but not committed yet.

kdePackages = prev.kdePackages.overrideScope(kdeFinal: kdePrev: {
  powerdevil = kdePrev.powerdevil.overrideAttrs (prevPdAttrs: {
    src = builtins.fetchGit {
      url = "file:///home/eliasp/code-repositories/public/KDE/plasma/powerdevil";
      rev = "f731c18e377b87c57f7205d9c1812a34f588c577";
    };
  });
});

Using the worktree of a local repository

Note: Since this relies on reading directly from the filesystem during the build, the impure mode has to be used, e.g.: nixos-rebuild --impure …

Now one might not want to commit each and every change during development to iterate more quickly, but to just rebuild after having saved the latest changes.

By just redirecting srcto the path of the working directory, where the required code resides, quick & dirty rebuilds are possible:

kdePackages = prev.kdePackages.overrideScope(kdeFinal: kdePrev: {
  powerdevil = kdePrev.powerdevil.overrideAttrs (prevPdAttrs: {
    src = /home/eliasp/code-repositories/public/KDE/plasma/powerdevil;
  });
});