Appimage/ru

AppImage - тип монолитных пакетов для приложений Linux. Содержит все зависимости приложения в одном файле, состоящем из исполняемого файла и встроенной файловой системы.

Использование

Запуск

В большинстве дистрибутивов все, что нужно сделать, это загрузить файл .AppImage, сделать его исполняемым chmod +x $AppImage и выполнить его. Однако это не работает в NixOS «из коробки», поскольку файлы AppImage обычно (если не всегда) зависят от определенных библиотек находящихся в жёстко заданных путях.

$ nix-shell -p appimage-run
$ appimage-run path/to/application.AppImage

Additional Packages

Some appimages still have issues, so you can override for additional pkgs such as

programs.appimage.enable = true;
programs.appimage.binfmt = true;
programs.appimage.package = pkgs.appimage-run.override 
{
  extraPkgs = pkgs: 
  [
    pkgs.icu
    pkgs.libxcrypt-legacy
    pkgs.python312
    pkgs.python312Packages.torch
  ]; 
};

Создание AppImage

См. руководство Nixpkgs manual on wrapping AppImage packages. Если кратко, AppImage извлекается, а все зависимости добавляются в качестве зависимостей сборки nix. Следующий пример представляет собой производную для программы Quba, которая также распространяется в виде AppImage.

{
  lib,
  appimageTools,
  fetchurl,
}:

let
  version = "1.4.0";
  pname = "quba";

  src = fetchurl {
    url = "https://github.com/ZUGFeRD/quba-viewer/releases/download/v${version}/Quba-${version}.AppImage";
    hash = "sha256-EsTF7W1np5qbQQh3pdqsFe32olvGK3AowGWjqHPEfoM=";
  };

  appimageContents = appimageTools.extractType1 { inherit name src; };
in
appimageTools.wrapType2 rec {
  inherit pname version src;

  extraInstallCommands = ''
    substituteInPlace $out/share/applications/${pname}.desktop \
      --replace-fail 'Exec=AppRun' 'Exec=${meta.mainProgram}'
  '';

  meta = {
    description = "Viewer for electronic invoices";
    homepage = "https://github.com/ZUGFeRD/quba-viewer";
    downloadPage = "https://github.com/ZUGFeRD/quba-viewer/releases";
    license = lib.licenses.asl20;
    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
    maintainers = with lib.maintainers; [ onny ];
    platforms = [ "x86_64-linux" ];
  };
}

Зарегистрируйте файлы AppImage как исполняемый тип в binfmt_misc

Вы можете указать ядру Linux использовать интерпретатор (например, appimage-run) при выполнении определенных двоичных файлов через использование binfmt_misc, либо по расширению имени файла, либо по совпадению магических чисел. Приведенная ниже конфигурация NixOS регистрирует файлы AppImage (ELF-файлы с магическим числом "AI" + 0x02) для запуска с помощью appimage-run в качестве интерпретатора.

programs.appimage = {
  enable = true;
  binfmt = true;
};

Таким образом файлы AppImage могут вызываться напрямую, как если бы они были обычными программами