Appimage/ja

AppImage is a monolithic packaging format for linux applications. It contains all dependencies in one file that is composed of an executable with a tacked on filesystem.

使い方

実行

ほとんどのLinuxディストリビューションでは、.AppImageファイルをダウンロードし、それを実行可能ファイルchmod +x $AppImageにして実行するだけです。ただし、AppImageファイルは通常（常にではないにしても）ハードコードされたパス内の特定のシステムライブラリに依存するため、NixOSではそのままでは機能しません。

$ nix-shell -p appimage-run
$ appimage-run $AppImageFile

パッケージング

nixpkgs manual on wrapping AppImage packagesを参照してください。要するに、AppImageが抽出され、依存関係がnixビルド依存関係として追加されます。 次の例は、AppImageとしても配布されているプログラム、Qubaの派生です。

{
  lib,
  appimageTools,
  fetchurl,
}:

let
  version = "1.4.0";
  pname = "quba";
  name = "${pname}-${version}";

src = fetchurl {
    url = "https://github.com/ZUGFeRD/quba-viewer/releases/download/v${version}/Quba-${version}.AppImage";
    hash = "sha256-EsTF7W1np5qbQQh3pdqsFe32olvGK3AowGWjqHPEfoM=";
  };

appimageContents = appimageTools.extractType1 { inherit name src; };
in
appimageTools.wrapType1 {
  inherit name src;

extraInstallCommands = ''
    mv $out/bin/${name} $out/bin/${pname}
    install -m 444 -D ${appimageContents}/${pname}.desktop -t $out/share/applications
    substituteInPlace $out/share/applications/${pname}.desktop \
      --replace-fail 'Exec=AppRun' 'Exec=${pname}'
    cp -r ${appimageContents}/usr/share/icons $out/share
  '';

meta = {
    description = "Viewer for electronic invoices";
    homepage = "https://github.com/ZUGFeRD/quba-viewer";
    downloadPage = "https://github.com/ZUGFeRD/quba-viewer/releases";
    license = lib.licenses.asl20;
    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
    maintainers = with lib.maintainers; [ onny ];
    platforms = [ "x86_64-linux" ];
  };
}

設定

AppImageファイルタイプをバイナリタイプとしてbinfmt_miscに登録する

You can tell the Linux kernel to use an interpreter (e.g. appimage-run) when executing certain binary files through the use of binfmt_misc, either by filename extension or magic number matching. Below NixOS configuration registers AppImage files (ELF files with magic number "AI" + 0x02) to be run with appimage-run as interpreter.

NixOS 24.05からは、binfmtオプションがあります：

programs.appimage = {
  enable = true;
  binfmt = true;
};

この方法では、AppImageファイルを通常のプログラムのように直接呼び出すことができます。