Bolt-launcher

Note for RS3 users

Because RuneScape still depends on EOL OpenSSL 1.1, running it on the latest NixOS currently requires a workaround.

More info here

Snippets with flakes:

❄︎ flake.nix

{
  inputs.nixpkgs-bolt-launcher.url = "https://channels.nixos.org/nixos-26.05/nixexprs.tar.zst";
  inputs.nixpkgs.url = "https://channels.nixos.org/nixos-unstable/nixexprs.tar.zst"; # or the latest stable, currently nixos-26.05

  outputs =
    { nixpkgs-bolt-launcher, nixpkgs, ... }@inputs:
    {
      nixosConfigurations.yourSystem = nixpkgs.lib.nixosSystem {
        modules = [
          ./configuration.nix
          ./hardware-configuration.nix
        ];
        specialArgs = { inherit inputs; };
      };
    };
}

❄︎ configuration.nix

{ inputs, pkgs, ... }:

{
  nixpkgs.overlays = [
    (final: prev: {
      bolt-launcher =
        let
          pkgs-bolt-launcher = import inputs.nixpkgs-bolt-launcher {
            inherit (pkgs.stdenv.hostPlatform) system;
            config.permittedInsecurePackages = [
              "openssl-1.1.1w"
            ];
          };
        in
        pkgs-bolt-launcher.bolt-launcher;
    })
  ];

  environment.systemPackages = with pkgs; [
    (bolt-launcher.override { enableRS3 = true; })
  ];
}