Swayidle

Swayidle is an idle management daemon for Wayland.

Installation

Standalone

❄︎ /etc/nixos/configuration.nix

environment.systemPackages = with pkgs; [
  swayidle
];

Home Manager - Standalone

❄︎ /etc/nixos/home.nix

services.swayidle.enable = true;

Home Manager - Through Sway

❄︎ /etc/nixos/home.nix

programs.sway.extraPackages = with pkgs; [swayidle];

Configuration

Swayidle has a lot of flexibility in its setup, but what is usually done is as follows:

1. Send notification before doing the following
2. Lock screen (typically Swaylock is used)
3. Turn off the screen (Note that the command may differ among window managers)
4. Suspend the system

which could be set using services.swayidle.timeouts. services.swayidle.events is useful to make the behavior consistent with the above in case systemctl suspend, loginctl lock-session are manually run.

Additional options may be found within the Home Manager Appendix under services.swayidle.

❄︎ ~/.config/home-manager/home.nix

services.swayidle =
let
  # Lock command
  lock = "${pkgs.swaylock}/bin/swaylock --daemonize";
  # TODO: modify "display" function based on your window manager
  # Sway
  display = status: "${pkgs.sway}/bin/swaymsg 'output * power ${status}'";
  # Hyprland
  # display = status: "hyprctl dispatch dpms ${status}";
  # Niri
  # display = status: "${pkgs.niri}/bin/niri msg action power-${status}-monitors";
in
{
  enable = true;
  timeouts = [
    {
      timeout = 15; # in seconds
      command = "${pkgs.libnotify}/bin/notify-send 'Locking in 5 seconds' -t 5000";
    }
    {
      timeout = 20;
      command = lock;
    }
    {
      timeout = 25;
      command = display "off";
      resumeCommand = display "on";
    }
    {
      timeout = 30;
      command = "${pkgs.systemd}/bin/systemctl suspend";
    }
  ];
  events = [
    {
      event = "before-sleep";
      # adding duplicated entries for the same event may not work
      command = (display "off") + "; " + lock;
    }
    {
      event = "after-resume";
      command = display "on";
    }
    {
      event = "lock";
      command = (display "off") + "; " + lock;
    }
    {
      event = "unlock";
      command = display "on";
    }
  ];
};

See the man page for further information.