Disko/ru

[Disko] это утилита и модуль Nixos для декларативной разметки дисков.

[Документация Disko]

Использование

Следующий пример создаёт новую таблицу разделов GPT для диска /dev/vda включая два раздела для EFI boot и корневой раздел файловой системы bcachefs.

disko-config.nix

{
  disko.devices = {
    disk = {
      main = {
        device = "/dev/vda";
        type = "disk";
        content = {
          type = "gpt";
          partitions = {
            ESP = {
              end = "500M";
              type = "EF00";
              content = {
                type = "filesystem";
                format = "vfat";
                mountpoint = "/boot";
              };
            };
            root = {
              name = "root";
              end = "-0";
              content = {
                type = "filesystem";
                format = "bcachefs";
                mountpoint = "/";
              };
            };
          };
        };
      };
    };
  };
}

Следующая команда применит расположение дисков, указанное в конфигурации, и смонтирует их после этого. Внимание: При этом все данные на диске будут удалены.

Warning: Комманды Disko сотрут все данные на вашем диске и переформатируют его в соответствии с заданной конфигурацией.

Warning: The disko commands will erase all existing data on your disk and repartition it according to the given configuration.

# sudo nix run github:nix-community/disko -- --mode disko ./disko-config.nix

В качестве альтернативы можно использовать конфигурацию разметки диска в удаленном репозитории, содержащем файл flake.nix, как точку входа. Параметр --arg задает целевой диск /dev/sda.

# sudo nix run github:nix-community/disko -- --mode zap_create_mount ./disko-config.nix

Приведенные выше команды требуют наличия в вашей системе функций Flake.

Чтобы убедиться, что оба раздела смонтированы правильно, выполните команду

# mount | grep /mnt

Настройка

Если базовая система NixOS была установлена на макет раздела, развёртываемого с помощью Disko, сам конфиг диска может быть интегрирован в систему. Сначала скопируйте файл, например disko-config.nix, в каталог конфигурации системы

# cp disko-config.nix /etc/nixos/

Добавьте модуль Disko в систему с поддержкой Flake. Вставьте нужный входной файл и ссылайтесь на него и на ваш файл disko-config.nix в разделе Модулей.

/etc/nixos/flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.05";
    disko.url = "github:nix-community/disko";
    disko.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs = {self, nixpkgs, disko, ...}@inputs: {

    nixosConfigurations.mysystem = inputs.nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs.inputs = inputs;
      modules = [
        disko.nixosModules.disko
        ./disko-config.nix
        {
          disko.devices.main.device = nixpkgs.lib.mkForce "/dev/vda";
        }
        ./configuration.nix
      ];
    };
  };
}

Убедитесь, что в файле /etc/nixos/hardware-configuration.nix нет автоматически генерируемых записей опций fileSystems в /etc/nixos/hardware-configuration.nix. Disko автоматически сгенерирует их за вас. Пересоберите систему, чтобы применить конфигурацию Disko.