Appimage/zh

AppImage 是一种 Linux 应用程序的单体打包格式。它将所有依赖项都包含在一个文件中，该文件由一个可执行文件和一个附加的文件系统组成。

用法

运行

在大多数发行版中，只需下载 .AppImage 文件，使用 chmod +x $AppImage 使其可执行，然后执行即可。但这在 NixOS 中无法直接使用，因为 AppImage 文件通常（即使并非总是）依赖于硬编码路径中的某些系统库。

$ nix-shell -p appimage-run
$ appimage-run $AppImageFile

打包

请参阅 nixpkgs 手册中包装 AppImage 软件的部分。简而言之，提取 AppImage，并将所有依赖项添加为 nix 构建依赖项。 以下示例是 Quba 程序的 Derivation，它以 AppImage 的形式分发。

{
  lib,
  appimageTools,
  fetchurl,
}:

let
  version = "1.4.0";
  pname = "quba";
  name = "${pname}-${version}";

src = fetchurl {
    url = "https://github.com/ZUGFeRD/quba-viewer/releases/download/v${version}/Quba-${version}.AppImage";
    hash = "sha256-EsTF7W1np5qbQQh3pdqsFe32olvGK3AowGWjqHPEfoM=";
  };

appimageContents = appimageTools.extractType1 { inherit name src; };
in
appimageTools.wrapType1 {
  inherit name src;

extraInstallCommands = ''
    mv $out/bin/${name} $out/bin/${pname}
    install -m 444 -D ${appimageContents}/${pname}.desktop -t $out/share/applications
    substituteInPlace $out/share/applications/${pname}.desktop \
      --replace-fail 'Exec=AppRun' 'Exec=${pname}'
    cp -r ${appimageContents}/usr/share/icons $out/share
  '';

meta = {
    description = "Viewer for electronic invoices";
    homepage = "https://github.com/ZUGFeRD/quba-viewer";
    downloadPage = "https://github.com/ZUGFeRD/quba-viewer/releases";
    license = lib.licenses.asl20;
    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
    maintainers = with lib.maintainers; [ onny ];
    platforms = [ "x86_64-linux" ];
  };
}

配置

将 AppImage 文件作为二进制类型注册到 binfmt_misc

您可以通过 binfmt_misc 来告诉 Linux 内核在执行某些二进制文件时使用哪个解释器（例如 appimage-run），具体方式可以通过文件扩展名或魔数匹配来实现。下面的 NixOS 配置会注册 AppImage 文件（魔数为“AI”+ 0x02 的 ELF 文件），并使用 appimage-run 作为解释器运行。

从 NixOS 24.05 开始，有一个 binfmt 选项：

programs.appimage = {
  enable = true;
  binfmt = true;
};

这样 AppImage 文件就可以像普通程序一样直接调用