fish
fish, the Friendly Interactive Shell, is a command shell designed around user-friendliness.
Installation
NixOS System Installation
To install fish for a user on a regular nixos system:
programs.fish.enable = true;
users.extraUsers.myuser = {
...
shell = pkgs.fish;
};
Replace myuser with the appropriate username.
/etc/passwd) may cause issues, particularly for the root user, because fish is not POSIX compliant. While using fish as the default shell for regular users is generaly safe, caution is still advised. See #Setting fish as default shell for recommendations and mitigations.Home Manager
For a user-specific installation managed by Home Manager, use the following configuration:
home-manager.users.myuser = {
programs.fish.enable = true;
};
Replace myuser with the appropriate username.
You can enable the fish shell and manage fish configuration and plugins with Home Manager, but to enable vendor fish completions provided by Nixpkgs you will also want to enable the fish shell:
programs.fish.enable = true;
Configuration
Available fish plugins packaged in Nixpkgs can be found via the fishPlugins package set.
NixOS System Configuration
To enable fish plugins system-wide, add your preferred plugins to `environment.systemPackages`:
programs.fish = {
enable = true;
interactiveShellInit = ''
set fish_greeting # Disable greeting
'';
};
environment.systemPackages = with pkgs; [
...
fishPlugins.done
fishPlugins.fzf-fish
fishPlugins.forgit
fishPlugins.hydro
fzf
fishPlugins.grc
grc
# Use 3rd-party fish plugins manually packaged.
(pkgs.callPackage ../fish-colored-man.nix {buildFishPlugin = pkgs.fishPlugins.buildFishPlugin; } )
];
Example of a file containing the definition of a fish plugin.
{
lib,
buildFishPlugin,
fetchFromGitHub,
}:
buildFishPlugin {
pname = "fish-colored-man";
version = "0-unstable-20240416";
src = fetchFromGitHub {
owner = "decors";
repo = "fish-colored-man";
rev = "1ad8fff696d48c8bf173aa98f9dff39d7916de0e";
hash = "sha256-uoZ4eSFbZlsRfISIkJQp24qPUNqxeD0JbRb/gVdRYlA=";
};
}
For a full list of fish module options, refer to programs.fish.
Home Manager
An example configuration in Home Manager for adding plugins and changing options could look like this:
home-manager.users.myuser = {
programs.fish = {
enable = true;
interactiveShellInit = ''
set fish_greeting # Disable greeting
'';
plugins = [
# Enable a plugin (here grc for colorized command output) from nixpkgs
{ name = "grc"; src = pkgs.fishPlugins.grc.src; }
# Manually packaging and enable a plugin
{
name = "z";
src = pkgs.fetchFromGitHub {
owner = "jethrokuan";
repo = "z";
rev = "e0e1b9dfdba362f8ab1ae8c1afc7ccf62b89f7eb";
sha256 = "0dbnir6jbwjpjalz14snzd3cgdysgcs3raznsijd6savad3qhijc";
};
}
];
};
};
For the full list of available home-manager options for fish, refer to the module source.
Tips and tricks
Setting fish as the default shell
It is possible to set fish as the interactive non-login shell for your terminal emulator without setting it as the login shell (the one in /etc/passwd).
As this is usually a user-wise setting, to configure the terminal emulator you will need to either modify its config file, or use home-manager
Setting fish as default for Kitty
Using Home Manager:
programs.kitty = {
enable = true;
shellIntegration.enableFishIntegration = true;
settings = {
shell = "fish";
};
};
Note: the shellIntegration.enableFishIntegration = true; is not required for setting fish as default, but provides other useful quality-of-life features, see https://sw.kovidgoyal.net/kitty/shell-integration/.
For use without home-manager, refer to https://sw.kovidgoyal.net/kitty/conf/#opt-kitty.shell and https://sw.kovidgoyal.net/kitty/conf/#opt-kitty.shell_integration.
Setting fish as default for Gnome Console
Using Home Manager:
home-manager.users.myuser = {
dconf = {
enable = true;
settings."org/gnome/Console" = {
shell = [ "fish" ];
};
};
};
Setting fish as the login shell
Using fish as the the login shell can cause compatibility issues. For example, certain recovery environments such as systemd's emergency mode to be completely broken when fish was set as the login shell. ArchWiki presents an alternative solution, keeping bash as the system shell but having it exec fish when run interactively.
Do note that even the following code is not full-proof, and should only be used with a thorough understanding. Prefer Setting fish as the default shell.
Here is one solution, which launches fish unless the parent process is already fish:
programs.bash = {
interactiveShellInit = ''
# "check if parent process is not fish" && "make nested shells work properly"
if grep -qv fish /proc/$PPID/comm && [[ $SHLVL == [12] ]]; then
# set $SHELL for better integration with programs like nix shell, tmux, etc.
SHELL=${pkgs.fish}/bin/fish exec fish
fi
'';
};
For a more detailed explanation, please see the aforementioned ArchWiki page.
↵If you still want to set fish as the login shell, see Command Shell#Changing the default shell.
Running fish interactively with zsh as system shell on darwin
Zsh users on darwin will need to use a modified version of the above snippet. As written, it presents two incompatibilities. First, being BSD-derived, MacOS's ps command accepts different options. Second, this is a script intended for bash, not zsh. MacOS uses zsh as its default shell.
programs.zsh = {
initExtra = ''
if [[ $(ps -o command= -p "$PPID" | awk '{print $1}') != 'fish' ]]
then
exec fish -l
fi
''
};
Disable man page generation
Some users suffer from slow build due to fish enabling `documentation.man.generateCaches`. You may force false.
documentation.man.generateCaches = false;
For home-manager users, man cache needs to be disabled in programs
programs.man.generateCaches = false;
Show that you are in a nix-shell
Add this to the fish_prompt function (usually placed in ~/.config/fish/functions/fish_prompt.fish):
set -l nix_shell_info (
if test -n "$IN_NIX_SHELL"
echo -n "<nix-shell> "
end
)
nix shell command, as it doesn't set IN_NIX_SHELL variable. You can instead check if $SHLVL is > 1, or check if $PATH contains paths from /nix/store (which get added at the beginning of the $PATH when you enter nix shell). See https://github.com/NixOS/nix/issues/6677 for more context and workarounds.and $nix_shell_info to the echo in that function, e.g.:
echo -n -s "$nix_shell_info ~>"
Now your prompt looks like this:
- outside:
~> - inside:
<nix-shell> ~>
You can directly start nix-shell in fish with nix-shell --run fish.
Environments
Here are some examples of helper functions that put you in a nix-shell with the given packages installed.
You can either put these in programs.fish.functions with home-manager or in ~/.config/fish/functions/fish_prompt.fish without.
haskellEnv
function haskellEnv
nix-shell -p "haskellPackages.ghcWithPackages (pkgs: with pkgs; [ $argv ])"
end
# Invocation: haskellEnv package1 packages2 .. packageN
pythonEnv
function pythonEnv --description 'start a nix-shell with the given python packages' --argument pythonVersion
if set -q argv[2]
set argv $argv[2..-1]
end
for el in $argv
set ppkgs $ppkgs "python"$pythonVersion"Packages.$el"
end
nix-shell -p $ppkgs
end
# Invocation: pythonEnv 3 package1 package2 .. packageN
# or: pythonEnv 2 ..