Eintopf

Eintopf is a community event calendar for groups and places.

Setup

A minimal local example setup would look like this

environment.etc."eintopf-secrets".text = ''
EINTOPF_ADMIN_PASSWORD=test123
'';

services.eintopf = {
  enable = true;
  settings = {
    EINTOPF_ADMIN_EMAIL = "test@example.org";
    EINTOPF_BASE_URL = "http://localhost:3333";
    EINTOPF_OSM_TILE_CACHE_DIR = "/var/lib/eintopf/osm";
    EINTOPF_OSM_TILE_SERVER = "https://tile.openstreetmap.org/{z}/{x}/{y}.png";
  };
  secrets = [ /etc/eintopf-secrets ];
};

The web service will be available at http://localhost:3333. The administration login page is available at http://localhost:3333/backstage where you can use the credentials specified above.

Configuration

Templates

Following example packages the "karlsunruh" template and set it as default for Eintopf.

{ pkgs, ... }:
let

  template-karlsunruh = pkgs.stdenv.mkDerivation {
    name = "karlsunruh";
    src = pkgs.fetchFromGitLab {
      domain = "git.project-insanity.org";
      owner = "onny";
      repo = "eintopf-karlsunruh";
      rev = "d762afc3fbd8e0a88d9752ad59aa5129da921982";
      hash = "";
    };
    makeFlags = [ "DESTDIR=$(out)" ];
  };

in
{

  services.eintopf = {
    enable = true;
    settings = {
      EINTOPF_THEMES = "eintopf,${template-karlsunruh}";
    };
  };

}

Tips and tricks

Sync events from Radar to Eintopf

The following script can be imported into the NixOS system configuration and will runs every half an hour to sync events from a given Radar group id to a specific target Eintopf instance.

Import the module and script into your system flake.nix file

{
  inputs = {
    eintopf-radar-sync.url = "git+https://git.project-insanity.org/onny/eintopf-radar-sync.git";
    [...]
  };

  outputs = {self, nixpkgs, ...}@inputs: {

    nixosConfigurations.my_system = inputs.nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs.inputs = inputs;
      modules = [
        inputs.eintopf-radar-sync.nixosModule

        ({ pkgs, ... }:{

          nixpkgs.overlays = [
            inputs.eintopf-radar-sync.overlay
          ];

        })

        ./configuration.nix

      ];
    };
  };
}

Enable the sync service in your system configuration by adding following snippet. Replace the setting variables according to your setup

environment.etc."eintopf-radar-sync-secrets".text = ''
EINTOPF_AUTHORIZATION_TOKEN=foobar23
'';

services.eintopf-radar-sync = {
  enable = true;
  settings = {
    EINTOPF_URL = "https://karlsunruh.project-insanity.org";
    RADAR_GROUP_ID = "436012";
  };
  secrets = [ /etc/eintopf-radar-sync-secrets ];
};

Get the authorization token through login request in the Eintopf Swagger api interface, for example https://karlsunruh.project-insanity.org/api/v1/swagger#/auth/login