Аппаратное Ускорение Видео

Ускорение воспроизведения видео в NixOS обычно осуществляется путем добавления соответствующих пакетов в hardware.opengl.extraPackages.

Установка

Intel

❄︎ /etc/nixos/configuration.nix

{
  hardware.graphics = {
    enable = true;
    extraPackages = with pkgs; [
      intel-media-driver # For Broadwell (2014) or newer processors. LIBVA_DRIVER_NAME=iHD
      intel-vaapi-driver # For older processors. LIBVA_DRIVER_NAME=i965
    ];
  };
  environment.sessionVariables = { LIBVA_DRIVER_NAME = "iHD"; }; # Optionally, set the environment variable
}

Note, intel-vaapi-driver still performs better for browsers (gecko/chromium based) on newer Skylake (2015) processors.^[1]

Для поддержки 32-битной версии используйте hardware.graphics.extraPackages32:

❄︎ /etc/nixos/configuration.nix

{
  hardware.graphics.extraPackages32 = with pkgs.pkgsi686Linux; [ intel-vaapi-driver ];
}

AMD

Конфигурация AMD (по крайней мере, для iGPU Ryzen 5) работает из коробки:

❄︎ /etc/nixos/configuration.nix

{
  hardware.graphics.enable = true;
}

NVIDIA

NVIDIA do not officially support accelerated video playback on Linux. A third-party implementation exists, but does not support Chrome^[2], and has significant limitations compared to the other implementations^[3].

NVIDIA users with a separate iGPU should generally prefer to use their iGPU for this, and therefore look to the above Intel and AMD sections instead.

Users with only an NVIDIA GPU can attempt to use the third party implementation; the package is added to hardware.graphics.extraPackages by default, but it requires some additional setup to be useful^[4]:

❄︎ /etc/nixos/configuration.nix

{ config, lib, ...}: {
  environment.variables.LIBVA_DRIVER_NAME = "nvidia"

  # If used with Firefox
  environment.variables.MOZ_DISABLE_RDD_SANDBOX = "1";

  programs.firefox.preferences = let
    ffVersion = config.programs.firefox.package.version;
  in {
    "media.ffmpeg.vaapi.enabled" = lib.versionOlder ffVersion "137.0.0";
    "media.hardware-video-decoding.force-enabled" = lib.versionAtLeast ffVersion "137.0.0";
    "media.rdd-ffmpeg.enabled" = lib.versionOlder ffVersion "97.0.0";

    "gfx.x11-egl.force-enabled" = true;
    "widget.dmabuf.force-enabled" = true;

    # Set this to true if your GPU supports AV1.
    #
    # This can be determined by reading the output of the
    # `vainfo` command, after the driver is enabled with
    # the environment variable.
    "media.av1.enabled" = false;
  };
}

Проверьте вашу конфигурацию

Вы можете протестировать вашу конфигурацию выполнив: nix-shell -p libva-utils --run vainfo

See Arch Linux wiki#Hardware video acceleration for more information.

Приложения

Chromium

См. Chromium#Accelerated_video_playback.

Firefox

MPV

Вы можете разместить следующую конфигурацию в ~/.config/mpv/mpv.conf:

hwdec=auto

See Arch Linux wiki#mpv.

Also see

Arch Linux wiki#Hardware video acceleration.
nixos-hardware has example configurations for various types of hardware.

[1] ttps://github.com/intel/media-driver/issues/1024

[2] ttps://github.com/elFarto/nvidia-vaapi-driver#chrome

[3] ttps://github.com/elFarto/nvidia-vaapi-driver#codec-support

[4] ttps://github.com/elFarto/nvidia-vaapi-driver#configuration

[1]

[2]

[3]

[4]